Actual source code: test7f.F90
1: !
2: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
3: ! SLEPc - Scalable Library for Eigenvalue Problem Computations
4: ! Copyright (c) 2002-, Universitat Politecnica de Valencia, Spain
5: !
6: ! This file is part of SLEPc.
7: ! SLEPc is distributed under a 2-clause BSD license (see LICENSE).
8: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
9: !
10: ! Program usage: mpiexec -n <np> ./test7f [-help] [-n <n>] [all SLEPc options]
11: !
12: ! Description: Simple example that solves an eigensystem with the EPS object.
13: ! Same problem as ex1f but with simplified output.
14: !
15: ! The command line options are:
16: ! -n <n>, where <n> = number of grid points = matrix size
17: !
18: ! ----------------------------------------------------------------------
19: !
20: program main
21: #include <slepc/finclude/slepceps.h>
22: use slepceps
23: implicit none
25: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
26: ! Declarations
27: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
28: !
29: ! Variables:
30: ! A operator matrix
31: ! eps eigenproblem solver context
33: Mat A
34: EPS eps
35: EPSType tname
36: PetscInt n, i, Istart, Iend
37: PetscInt nev, nini
38: PetscInt col(3)
39: PetscInt i0, i1, i2, i3
40: PetscMPIInt rank
41: PetscErrorCode ierr
42: PetscBool flg
43: PetscScalar value(3), one
44: Vec v(1)
46: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
47: ! Beginning of program
48: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
50: PetscCallA(SlepcInitialize(PETSC_NULL_CHARACTER,ierr))
51: PetscCallMPIA(MPI_Comm_rank(PETSC_COMM_WORLD,rank,ierr))
52: n = 30
53: PetscCallA(PetscOptionsGetInt(PETSC_NULL_OPTIONS,PETSC_NULL_CHARACTER,'-n',n,flg,ierr))
55: if (rank .eq. 0) then
56: write(*,100) n
57: endif
58: 100 format (/'1-D Laplacian Eigenproblem, n =',I3,' (Fortran)')
60: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
61: ! Compute the operator matrix that defines the eigensystem, Ax=kx
62: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
64: PetscCallA(MatCreate(PETSC_COMM_WORLD,A,ierr))
65: PetscCallA(MatSetSizes(A,PETSC_DECIDE,PETSC_DECIDE,n,n,ierr))
66: PetscCallA(MatSetFromOptions(A,ierr))
68: i0 = 0
69: i1 = 1
70: i2 = 2
71: i3 = 3
72: PetscCallA(MatGetOwnershipRange(A,Istart,Iend,ierr))
73: if (Istart .eq. 0) then
74: i = 0
75: col(1) = 0
76: col(2) = 1
77: value(1) = 2.0
78: value(2) = -1.0
79: PetscCallA(MatSetValues(A,i1,[i],i2,col,value,INSERT_VALUES,ierr))
80: Istart = Istart+1
81: endif
82: if (Iend .eq. n) then
83: i = n-1
84: col(1) = n-2
85: col(2) = n-1
86: value(1) = -1.0
87: value(2) = 2.0
88: PetscCallA(MatSetValues(A,i1,[i],i2,col,value,INSERT_VALUES,ierr))
89: Iend = Iend-1
90: endif
91: value(1) = -1.0
92: value(2) = 2.0
93: value(3) = -1.0
94: do i=Istart,Iend-1
95: col(1) = i-1
96: col(2) = i
97: col(3) = i+1
98: PetscCallA(MatSetValues(A,i1,[i],i3,col,value,INSERT_VALUES,ierr))
99: enddo
101: PetscCallA(MatAssemblyBegin(A,MAT_FINAL_ASSEMBLY,ierr))
102: PetscCallA(MatAssemblyEnd(A,MAT_FINAL_ASSEMBLY,ierr))
104: PetscCallA(MatCreateVecs(A,v(1),PETSC_NULL_VEC,ierr))
105: one = 1.0
106: if (Istart .eq. 0) then
107: PetscCallA(VecSetValue(v(1),i0,one,INSERT_VALUES,ierr))
108: endif
109: PetscCallA(VecAssemblyBegin(v(1),ierr))
110: PetscCallA(VecAssemblyEnd(v(1),ierr))
112: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
113: ! Create the eigensolver and display info
114: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
116: ! ** Create eigensolver context
117: PetscCallA(EPSCreate(PETSC_COMM_WORLD,eps,ierr))
119: ! ** Set operators. In this case, it is a standard eigenvalue problem
120: PetscCallA(EPSSetOperators(eps,A,PETSC_NULL_MAT,ierr))
121: PetscCallA(EPSSetProblemType(eps,EPS_HEP,ierr))
123: ! ** Set solver parameters at runtime
124: PetscCallA(EPSSetFromOptions(eps,ierr))
126: ! ** Set initial vectors
127: nini = 1
128: PetscCallA(EPSSetInitialSpace(eps,nini,v,ierr))
130: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
131: ! Solve the eigensystem
132: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
134: PetscCallA(EPSSolve(eps,ierr))
136: ! ** Optional: Get some information from the solver and display it
137: PetscCallA(EPSGetType(eps,tname,ierr))
138: if (rank .eq. 0) then
139: write(*,120) tname
140: endif
141: 120 format (' Solution method: ',A)
142: PetscCallA(EPSGetDimensions(eps,nev,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,ierr))
143: if (rank .eq. 0) then
144: write(*,130) nev
145: endif
146: 130 format (' Number of requested eigenvalues:',I2)
148: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
149: ! Display solution and clean up
150: ! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
152: PetscCallA(EPSErrorView(eps,EPS_ERROR_RELATIVE,PETSC_NULL_VIEWER,ierr))
153: PetscCallA(EPSDestroy(eps,ierr))
154: PetscCallA(MatDestroy(A,ierr))
155: PetscCallA(VecDestroy(v(1),ierr))
157: PetscCallA(SlepcFinalize(ierr))
158: end
160: !/*TEST
161: !
162: ! test:
163: ! suffix: 1
164: ! args: -eps_nev 4 -eps_ncv 19
165: ! filter: sed -e "s/83791/83792/"
166: !
167: !TEST*/